***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Feb 18, 2020                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJA138L   D   G   S
*****param & model definition***
.model  dmos  nmos(
+    l = 1e-6		  w = 1e-6		level = 3
+  vto = 1.3		 kp = 0.4)
.model  dds   d(
+   is = 5.096e-14	  n = 1.056		   rs = 2.355e-1
+   eg = 1.115	)
.model  dbody d(
+   is = 5.096e-14	  n = 1.056		   rs = 2.355e-1
+  ikf = 2.265e-2	     trs1 = -1.021e-3
+  cjo = 7.077e-12	  m = 1.468e-1	   vj = 7.028e-1
+   bv = 66			ibv = 250e-6	 tbv1 = 1.045e-3
+   tt = 25n		ikf = 2.265e-2)
.model  inter  nmos(
+  vto = 0			 kp = 10		level = 1)
.model  dgd   d(
+  cjo = 6.376e-12	  m = 1.000e-1	   vj = 4.765e-1)
.param
+  cgs = 1.566e-11	cgd = 6.341e-12
+   rd = 1.000e-0		 ra = 8.000e-1	  
+ trd1 = 1.355e-2	     trd2 = 4.105e-5	
*****function & circuit***
rg	  G  1t   1
cgs	 1t   3   {cgs}    ic = 0
egv	 2t   3   table   {v(1t, S)} 
+((0.00 , 0.00 ),
+ (0.50 , 0.50 ),
+ (1.00 , 1.00 ),
+ (1.50 , 1.44 ),
+ (2.00 , 2.00 ),
+ (2.50 , 2.42 ),
+ (2.75 , 2.60 ),
+ (3.00 , 2.74 ),
+ (4.00 , 3.25 ),
+ (5.00 , 3.60 ),
+ (6.00 , 3.90 ),
+ (8.00 , 4.25 ),
+ (10.0 , 4.50 ),
+ (20.0 , 4.60 ),
+ (22.0 , 4.60 ))
egt	  1  2t   value = {3.702e-4*limit(v(2t,3),0,5)*limit((temp-25),-80,125)}
mmain	  2   1   3   3   dmos
rd	  D   4   {rd}    tc = {trd1},{trd2}
dds	  3   4   dds
dbody	  3   D   dbody
ra	  4   2   {ra} 
rs	  3   5   1e-4
ls	  5   S   0.001n 
m1     1t   8   6   6   inter
e1      8   6   4  1t   2
cgd	  7   4   {cgd}   ic = 0
rcgd    7   4   10meg
dgd     6   4   dgd
rdgd    4   6   10meg
m2      7   9  1t  1t   inter
e2      9  1t   4  1t   -2
.ends 
*$
